(玩電子) 電子技術學習與研究
                      當前位置:單片機教程網 >> 基礎教程 >> 瀏覽文章

                      24課:動態掃描顯示接口電路及程序

                      作者:佚名   來源:本站原創   點擊數:x  更新時間:2007年08月14日   【字體:

                          在單片機系統中動態掃描顯示接口是單片機中應用最為廣泛的一種顯示方式之一。其接口電路是把所有顯示器的8個筆劃段a-h同名端連在一起,而每一個顯示器的公共極COM是各自獨立地受I/O線控制。CPU向字段輸出口送出字形碼時,所有顯示器接收到相同的字形碼,但究竟是那個顯示器亮,則取決于COM端,而這一端是由I/O控制的,所以我們就能自行決定何時顯示哪一位了。而所謂動態掃描就是指我們采用分時的辦法,輪流控制各個顯示器的COM端,使各個顯示器輪流點亮。在http://www.z8768.com還有很多關于單片機顯示接口的文章,大家可以參考一下

                         在輪流點亮掃描過程中,每位顯示器的點亮時間是極為短暫的(約1ms),但由于人的視覺暫留現象及發光二極管的余輝效應,盡管實際上各位顯示器并非同時點亮,但只要掃描的速度足夠快,給人的印象就是一組穩定的顯示數據,不會有閃爍感。

                         下圖所示就是我們的單片機實驗板上的動態掃描接口。由89c51的P0口能灌入較大的電流,所以我們采用共陽的數碼管,并且不用限流電阻,而只是用兩只1N4004進行降壓后給數碼管供電,這里僅用了兩只,實際上還能擴充。它們的公共端則由PNP型三極管8550控制,顯然,如果8550導通,則對應的數碼管就能亮,而如果8550截止,則對應的數碼管就不可能亮,8550是由P2.7,P2.6控制的。這樣我們就能通過控制P27、P26達到控制某個數碼管亮或滅的目的。

                      下面的這個單片機程序,就是用實驗板上的數碼管顯示0和1。

                      FIRST EQU P2.7 ;第一位數碼管的位控制

                      SECOND EQU P2.6 ;第二位數碼管的位控制

                      DISPBUFF EQU 5AH ;顯示緩沖區為5AH和5BH

                      ORG 0000H

                      AJMP START

                      ORG 30H

                      START:

                      MOV SP,#5FH ;設置堆棧

                      MOV P1,#0FFH

                      MOV P0,#0FFH

                      MOV P2,#0FFH ;初始化,所顯示器,LED滅

                      MOV DISPBUFF,#0 ;第一位顯示0

                      MOV DISPBUFF+1,#1 ;第二握顯示1

                      LOOP:

                      LCALL DISP ;調用顯示程序

                      AJMP LOOP

                      ;主程序到此結束

                      DISP:

                      PUSH ACC ;ACC入棧

                      PUSH PSW ;PSW入棧

                      MOV A,DISPBUFF ;取第一個待顯示數

                      MOV DPTR,#DISPTAB ;字形表首地址

                      MOVC A,@A+DPTR ;取字形碼

                      MOV P0,A ;將字形碼送P0位(段口)

                      CLR FIRST ;開第一位顯示器位口

                      LCALL DELAY ;延時1毫秒

                      SETB FIRST ;關閉第一位顯示器(開始準備第二位的數據)

                      MOV A,DISPBUFF+1 ;取顯示緩沖區的第二位

                      MOV DPTR,#DISPTAB

                      MOVC A,@A+DPTR

                      MOV P0,A ;將第二個字形碼送P0口

                      CLR SECOND ;開第二位顯示器

                      LCALL DELAY ;延時

                      SETB SECOND ;關第二位顯示

                      POP PSW

                      POP ACC

                      RET

                      DELAY: ;延時1毫秒

                      PUSH PSW

                      SETB RS0

                      MOV R7,#50

                      D1: MOV R6,#10

                      D2: DJNZ R6,$

                      DJNZ R7,D1

                      POP PSW

                      RET

                      DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H

                      END

                      從上面的單片機例程中能看出,動態掃描顯示必須由CPU持續地調用顯示程序,才能保證持續持續的顯示。

                         上面的這個程序能實現數字的顯示,但不太實用,為什么呢?這里僅是顯示兩個數字,并沒有做其他的工作,因此,兩個數碼管輪流顯示1毫秒,沒有問題,實際的工作中,當然不可能只顯示兩個數字,還是要做其他的事情的,這樣在二次調用顯示程序之間的時間間隔就不一不定了,如果時間間隔比較長,就會使顯示不連續。而實際工作中是很難保證所有工作都能在很短時間內完成的。況且這個顯示程序也有點“浪費”,每個數碼管顯示都要占用1個毫秒的時間,這在很多合是不允許的,怎么辦呢?我們能借助于定時器,定時時間一到,產生中斷,點亮一個數碼管,然后馬上返回,這個數碼管就會一直亮到下一次定時時間到,而不用調用延時程序了,這段時間能留給主程序干其他的事。到下一次定時時間到則顯示下一個數碼管,這樣就很少浪費了。

                      Counter EQU 59H ;計數器,顯示程序通過它得知現正顯示哪個數碼管

                      FIRST EQU P2.7 ;第一位數碼管的位控制

                      SECOND EQU P2.6 ;第二位數碼管的位控制

                      DISPBUFF EQU 5AH ;顯示緩沖區為5AH和5BH

                      ORG 0000H

                      AJMP START

                      ORG 000BH ;定時器T0的入口

                      AJMP DISP ;顯示程序

                      ORG 30H

                      START:

                      MOV SP,#5FH ;設置堆棧

                      MOV P1,#0FFH

                      MOV P0,#0FFH

                      MOV P2,#0FFH ;初始化,所顯示器,LED滅

                      MOV TMOD,#00000001B ;定時器T0工作于模式1(16位定時/計數模式)

                      MOV TH0,#HIGH(65536-2000)

                      MOV TL0,#LOW(65536-2000)

                      SETB TR0

                      SETB EA

                      SETB ET0

                      MOV Counter,#0 ;計數器初始化

                      MOV DISPBUFF,#0 ;第一位始終顯示0

                      MOV A,#0

                      LOOP:

                      MOV DISPBUFF+1,A ;第二位輪流顯示0-9

                      INC A

                      LCALL DELAY

                      CJNE A,#10,LOOP

                      MOV A,#0

                      AJMP LOOP ;在此中間能按排任意程序,這里僅作示范。

                      ;主程序到此結束

                      DISP: ;定時器T0的中斷響應程序

                      PUSH ACC ;ACC入棧

                      PUSH PSW ;PSW入棧

                      MOV TH0,#HIGH(65536-2000) ;定時時間為2000個周期,約2170微秒(11.0592M)

                      MOV TL0,#LOW(65536-2000)

                      SETB FIRST

                      SETB SECOND ;關顯示

                      MOV A,#DISPBUFF ;顯示緩沖區首地址

                      ADD A,Counter

                      MOV R0,A

                      MOV A,@R0 ;根據計數器的值取對應的顯示緩沖區的值

                      MOV DPTR,#DISPTAB ;字形表首地址

                      MOVC A,@A+DPTR ;取字形碼

                      MOV P0,A ;將字形碼送P0位(段口)

                      MOV A,Counter ;取計數器的值

                      JZ DISPFIRST ;如果是0則顯示第一位

                      CLR SECOND ;不然顯示第二位

                      AJMP DISPNEXT

                      DISPFIRST:

                      CLR FIRST ;顯示第一位

                      DISPNEXT:

                      INC Counter ;計數器加1

                      MOV A,Counter

                      DEC A ;如果計數器計到2,則讓它回0

                      DEC A

                      JZ RSTCOUNT

                      AJMP DISPEXIT

                      RSTCOUNT:

                      MOV Counter,#0 ;計數器的值只能是0或1

                      DISPEXIT:

                      POP PSW

                      POP ACC

                      RETI

                      DELAY: ;延時130毫秒

                      PUSH PSW

                      SETB RS0

                      MOV R7,#255

                      D1: MOV R6,#255

                      D2: NOP

                      NOP

                      NOP

                      NOP

                      DJNZ R6,D2

                      DJNZ R7,D1

                      POP PSW

                      RET

                      DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H

                      END

                          從上面的單片機程序能看出,動態顯示和靜態顯示相比,程序稍有點復雜,不過,這是值得的。這個程序有一定的通用性,只要改變端口的值及計數器的值就能顯示更多位數了。下面給出顯示程序的流程圖。<動態掃描程序框圖>

                       

                       

                       

                       

                       

                       

                       

                      發表評論】【告訴好友】【收藏此文】【關閉窗口

                      文章評論

                      富二代国产视频